Aplicaciones de la integral definida.

Práctica 6 (Específica de la asignatura de Cálculo Matemático en E.U.A.T.)

(Práctica elaborada a partir de las realizadas en cursos anteriores por los profesores María José Cáceres, Juanjo M. Nieto y Óscar Sánchez)

Introducción

En esta práctica veremos como calcular el área de regiones planas, la longitud de arcos de curvas, el área de superficies de revolución, el volumen de sólidos de revolución y el volumen de sólidos de secciones conocidas, todo ello como aplicación del concepto de integral definida.

Área de una región plana definida por una o dos curvas

Área de una región definida por la gráfica de una función y el eje horizontal

Dada una función  f : [a, b] -> R continua,  el área que queda entre la gráfica de  f , el eje OX  y las rectas verticales  x=a  y  x=b  viene dada por la expresión

			                (∫_a^b) |f(x)|dx . \(\+\ \ \)

Es claro que la dificultad de este cálculo es determinar los puntos, si los hay, donde  f  cambia de signo. Veamos un ejemplo.

f[x_] := x^3 - 3  x^2 + 1;
Plot[f[x], {x, -1, 3}];

Buscamos los puntos de corte con los ejes.

pcorte = NSolve[f[x] == 0, x]

Llamamos a tales puntos a, b y c.

a = x /. pcorte[[1]]
b = x /. pcorte[[2]]
c = x /. pcorte[[3]]

Dibujamos de nuevo y calculamos el área buscada. Para realizar el dibujo utilizaremos el comando FilledPlot para sombrear la región que nos interesa. Para poder usar FilledPlot hay que caragar previamente el paquete Graphics`FilledPlot`.

<< Graphics`FilledPlot`
FilledPlot[f[x], {x, a, c}];

Teniendo en cuenta que f es positiva antre a y b y que es negativa entre b y c, podemos ya calcular.

Integrate[f[x], {x, a, b}] - Integrate[f[x], {x, b, c}]

Observación

En versiones antiguas de Mathematica (la 3.0 por ejemplo) el uso del valor absoluto (Abs) en Integrate puede dar lugar a resultados erróneos. En las versiones modernas (la 5.2 por ejemplo) este problema parece haber sido resuelto.

Integrate[Abs[f[x]], {x, a, c}]

Integrate[Abs[f[x]], {x, a, b}]

Integrate[Abs[f[x]], {x, b, c}]

Área de una región limitada por dos funciones

Dadas dos funciones  f, g : [a, b] -> R continuas,  el área que queda entre la gráfica de f , la gráfica de g y las rectas verticales x=a y x=b es igual a

			                (∫_a^b) |f(x) - g(x)|dx .  \(\+\ \ \)

En este caso la dificultad está en determinar los puntos de corte, si los hay, de las dos gráficas. Veamos un ejemplo.

f[x_]:=Cos[x]; (*en rojo*)
g[x_]:=x^2-x-1; (*en azul*)
Plot[{f[x],g[x]},{x,-3,3},PlotStyle->{{RGBColor[1,0,0]},{RGBColor[0,0,1]}}];

Localizamos los puntos de corte entre f  y  g  y los guardamos. (Intenta buscarlos con NSolve).

FindRoot[f[x] == g[x], {x, -1}]
a = x /. %

FindRoot[f[x] == g[x], {x, 1}]
b = x /. %

Dibujamos la región concreta y calculamos el área buscada observando que f está por encima de g en [a,b].

FilledPlot[{f[x], g[x]}, {x, a, b}];

Integrate[f[x] - g[x], {x, a, b}]

Longitud de un arco de curva

Curva dada explícitamente

Cuando la curva está dada por una función derivable  f : [a, b] -> R, con f ' continua en [a,b], su longitud es igual a

			                (∫_a^b)(Sqrt[1 + (((f' (x)))^2)])dx . 

Veamos un ejemplo.

f[x_] := Tan[x]        
Plot[f[x], {x, -1.3, 1.3}];
longitud = 
        NIntegrate[Sqrt[1 + (f'[x])^2], {x, -1.3, 1.3}]

Curva dada en paramétricas

Cuando la curva está dada en paramétricas  α : [a, b] -> 
        (R^2),  α(t) = (x(t), y(t)), (siendo x(t), y(t) funciones derivables con continuidad en [a,b]) su longitud es igual a

			                (∫_a^b)(Sqrt[(((x' (t)))^2) + (((y' (t)))^2)])dt .\(\+\ \ \)
			                
Veamos el ejemplo de una curva llamada cardioide* (ecuación implícita ((((x^2) + (y^2) - a x))^2) = (a^2)(
          (x^2) + (y^2)), a > 0) cuya longitud es 8a.
Las paramétricas que damos aquí están definidas en [-∞,∞] pero por razones técnicas trabajaremos en [-30,30] para pintar y en [-60,60] en la integral, por lo que habrá un pequeño error al calcular la longitud.
          *Referencia:  http://www.mathcurve.com/courbes2d/cardioid/cardioid.shtml

a = 1;
x[t_] := 
        2  a (1 - t^2)/(1 + t^2)^2;
y[t_] := 4  a t/(1 + t^2)^2;
ParametricPlot[{x[t], y[t]}, {t, -30, 30}, 
        AspectRatio -> Automatic];

longitud = 
      NIntegrate[
        Sqrt[(x'[t])^2 + (y'[t])^2], {t, -60, 
          60}]

Veamos dos ejemplos más.

alfa[t_] := { 10  Cos[t], 5  Sin[t]};
ParametricPlot[alfa[t], {t, 0, 2 Pi}, 
        AspectRatio -> Automatic];
longitud = 
      NIntegrate[
        Sqrt[(alfa'[t][[1]])^2 + (alfa'[
                    t][[2]])^2], {t,  0, 2 Pi}]

curva[t_] := {Cos[3  t], Sin[2  t]};
ParametricPlot[curva[t], {t, 0,  Pi}, 
        AspectRatio -> Automatic];
longitud = 
      NIntegrate[
        Sqrt[(curva'[t][[1]])^2 + (curva'[
                    t][[2]])^2], {t,  0, Pi}]

Área de una superficie de revolución

Girando en torno a OX

Dada una función positiva y derivable  f : [a, b] -> R, con f ' continua en [a,b], generamos una superficie de revolución girando 360º la gráfica de f entre los puntos x=a y x=b en torno al eje OX. El área de la superficie resultante viene dada por la fórmula

			        		 2π(∫_a^b)f(x)(Sqrt[1 + (((f' (x)))^2)])dx . 

Veamos un ejemplo.

f[x_] := 
        1 + 1/(5.6 - x) + 1/2 Cos[x];
Plot[f[x], {x, 0, 5}, PlotRange -> {0, 3}, 
        AspectRatio -> Automatic];
ParametricPlot3D[{x, f[x] Cos[u], f[x] Sin[u]}, {x, 0, 
          5}, {u, -Pi/2, 3 Pi/2}];

El área será igual a

area = 
      2*Pi*NIntegrate[
          f[x] Sqrt[1 + (f'[x])^2], {x, 0, 5}]

Girando en torno a OY

Dada una función derivable f : [a, b] -> R,  donde a > 0 y con f ' continua en [a,b], generamos una superficie de revolución girando 360º la gráfica de f entre los puntos x=a y x=b en torno al eje OY. El área de la superficie resultante viene dada por la fórmula

					 2π(∫_a^b)x(Sqrt[1 + (((f' (x)))^2)])dx .\(\+\ \ \)

Veamos como ejemplo el área de media esfera (de radio 1).

f[x_] := -Sqrt[1 - x^2];
Plot[f[x], {x, 0, 1}, PlotRange -> {0, -1}, 
        AspectRatio -> Automatic];
ParametricPlot3D[{x Cos[u], x Sin[u], f[x]}, {x, 0, 
          1}, {u, -Pi/2, 3 Pi/2}];

Y el área será igual a (ya sabemos que será igual a 2π)

area = 
      2*Pi*Integrate[x Sqrt[1 + (f'[x])^2], {x, 0, 1}]

Volumen de un sólido de revolución

Método de discos (giros en torno a OX)

Dada una función positiva y continua  f : [a, b] -> R,  generamos un sólido de revolución girando 360º la región que queda bajo la gráfica de  f entre los puntos x=a y x=b en torno al eje OX. El volumen de la figura así construida viene dado por la fórmula

					π(∫_a^b)(((f(x)))^2)dx . \(\+\ \ \)

Veamos un ejemplo.

f[x_] := 
        1 + 1/(5.6 - x) + 1/2 Cos[x];
FilledPlot[f[x], {x, 0, 5}, PlotRange -> {0, 3}, 
        AspectRatio -> Automatic];
ParametricPlot3D[{{x, f[x] Cos[u], f[x] Sin[u]}, {5, 
            f[5] (x/5) Cos[u], f[5] (x/5) Sin[u]}}, {x, 0, 5}, {u, 
          0, 2 Pi}];

El volumen es:

volumen = Pi*NIntegrate[(f[x])^2, {x, 0, 5}]

La fórmula se llama de los discos porque se obtiene "sumando" las áreas de los discos que genera cada línea vertical de la región como vemos en la siguiente ilustración. (Recordamos aquí que una integral es en esencia una "suma infinita", por ello la "suma" de todas las áreas de cada disco, π (radio)^2= π (f(x))\(TraditionalForm\`\^2\),  da lugar a la integral anterior).

Método de tubos (giros en torno a OY)

Dada una función continua  f : [a, b] -> R,  donde a > 0, generamos un sólido de revolución girando 360º la región que queda bajo la gráfica de  f entre los puntos x=a y x=b en torno al eje OY. El volumen de la figura así construida viene dado por la fórmula

					 2π(∫_a^b)x f(x)dx .\(\+\ \ \)

Veamos un ejemplo.

f[x_] := 1/4 + Sqrt[1/4 - (x - 1)^2];   
FilledPlot[f[x], {x, 0.5, 1.5}];
ParametricPlot3D[{x Cos[u], x Sin[u], 
          f[x]}, {x, 0.5, 1.5}, {u, 0, 2 Pi}];

El volumen es:

volumen = 2*Pi*NIntegrate[x f[x], {x, 0.5, 1.5}]

La fórmula se llama de los tubos porque se obtiene "sumando" las áreas de los tubos que genera cada línea vertical de la región (recordamos aquí que una integral es en esencia una "suma infinita", por ello la "suma" de todas las áreas de cada tubo, 2π(base)(altura) = 2π x f(x)  da lugar a la integral).

Alguna variante

Podemos usar estas técnicas cuando la región a girar sea la comprendida entre dos funciones continuas f, g : [a, b] -> R. Generamos un sólido de revolución girando 360º la región que queda entre las gráficas de  f  y g respecto al eje OX y respecto al OY.

	 Si f(x) ≥ g(
                x) tenemos :      respecto OX -> π(∫_a^b)((((f(x)))^2)-(((g(x)))^2))  dx .  \(\+\ \)      
	 
 				      	 respecto OY -> 2π(∫_a^b)x (f(x) - g(x))dx .\(\+\ \ \)
 
Veamos un ejemplo gráfico.

f[x_] := -(x - 1)^2 + 
          5/2;   
g[x_] := (x - 1)^2 + 
        1/2;     
FilledPlot[{f[x], 
        g[x]}, {x, 0, 2}, PlotRange -> {0, 5/2}, 
      PlotStyle -> {{RGBColor[1, 0, 0]}, {RGBColor[0, 0, 
              0]}}];

Girando esta región respecto a OX y OY obtenemos las figuras que siguen.

ParametricPlot3D[{{x, f[x] Cos[u], f[x] Sin[u]}, {x, g[x] Cos[u], 
            g[x] Sin[u]}}, {x, 0, 2}, {u, 0,  
          2  Pi}];
ParametricPlot3D[{{x Cos[u], x Sin[u], f[x]}, {x Cos[u], 
            x Sin[u], g[x]}}, {x, 0, 2}, {u, 0, 2  Pi}];

Los respectivos volumenes son iguales a

volumenOX = 
      Pi*Integrate[(f[x])^2 - (g[x])^2, {x, 0, 
            2}]
volumenOY = 2*Pi*Integrate[x (f[x] - g[x]), {x, 0, 2}]

Un ejemplo aplicado de integrales impropias: Trompeta de Gabriel

f[x_] = 1/x;
FilledPlot[
        f[x], {x, 1. , 5. }];
ParametricPlot3D[{x,  
          f[x]  Cos[u], f[x]  Sin[u]}, {x, 1, 5. }, {u, 0, 
          2 Pi}];
volumen = 
        Limit[Pi*Integrate[(f[x])^2, {x, 1, M}], M -> ∞]      
area=Limit[
        2*Pi*Integrate[f[x] Sqrt[1 + (f'[x])^2], {x, 1, M}], 
        M -> ∞]

Volumen por secciones

Consideremos un sólido comprendido entre los puntos x = a  y  x = b. Sea  A(x)  el área de la sección del sólido resultante de la intersección con el palno perpendicular al eje OX en el punto x. Supongamos que la función  A:[a,b]-> R  así definida es continua. Entonces el volumen del sólido viene dado por la fórmula

			(∫_a^b)A(x)dx .\(\+\ \ \)

Veamos un ejemplo.

f[x_] := 
        1 + 1/(5.6 - x) + 1/2 Cos[x];
Plot[f[x], {x, 0, 5}, 
        PlotRange -> {0, 2}];
ParametricPlot3D[{{x, f[x] Cos[u], f[x] Sin[u]}, {5, 
            f[5] x/5 Cos[u], f[5] x/5  Sin[u]}}, {x, 0, 5}, {u, 0, 
          2 Pi}];

A la vista de la gráfica de  f(x), cada sección tiene una superficie igual a π (f(x))^2. Por tanto, el volumen vendrá dado por

π NIntegrate[(f[x])^2, {x, 0, 5}]

Observa que este resultado ya lo sabiamos por el ejemplo visto el método de discos para volúmenes de revolución.

Ejercicios

01.- Calcular el área de la región del plano limitada por las gráficas de las funciones  y = xsen(x+2)  e  y = 4cos(x)  entre los puntos x = -2  y  x = 2.

02.- Calcular la longitud del arco de la curva  f(x) = 6log(x)+7(Sqrt[(x^3)]) entre los puntos de abscisas  x = 1  y  x = 3.

03.- Halla el área de la región del plano entre la recta  x+y-3 = 0  y la curva  y = 6-3x-(x^2).

04.- Sea R la región del plano limitada por la parábola  y = 6-3x-x^2  y la recta  x+y-3 = 0. Hallar el volumen del cuerpo de revolución que engendra R al girar 
		a) alrededor de la recta  x = 3;
		b) alrededor de la recta  y = 0.

05.- Halla el volumen del sólido que resulta al girar el área bajo la parte positiva de la gráfica de y = -(x^2)+5 en torno al eje OX.

06.- Halla el área de la superficie que resulta al girar la curva del ejercicio anterior en torno al eje OX.

07.- Halla el volumen del cuerpo que queda al girar la región bajo la gráfica de la función coseno entre 0 y π/2, primero en torno al eje OX y luego en torno al eje OY.

08.- Con la función anterior, calcula el área de la superficie resultante al girar en torno a los dos ejes.

09.- Calcula una fórmula explícita para el volumen de una esfera.

10.- Encuentra una fórmula que dé el volumen de un cono de revolución.

11.- Con los comandos aquí expuestos, realiza los ejercicios del 20 al 29 de la relación de ejercicios de teoría.