Iteraciones de potencias complejas

Javier Pérez González
Departamento de Análisis Matemático
fjperez@ugr.es

Introducción

Una sucesión cuyo término n-ésimo viene dado en función de algunos de los términos anteriores se dice que es una sucesión recurrente. Ya hemos visto ejemplos de tales sucesiones en la lección anterior al estudiar los conjuntos de Julia y de Mandelbrot. Las llamadas "iteraciones de punto fijo" consistentes en iterar una función g a partir de un valor inicial (Subscript[x, 1]) para formar la sucesión dada por (Subscript[x, n + 1])=g((Subscript[x, n])) son un ejemplo de sucesiones recurrentes. En esta práctia vamos a estudiar sucesiones que se obtienen iterando potencias complejas. Veremos primero un caso particular que nos permitirá introducir y ejemplificar algunos conceptos usuales en el estudio de este tipo de sucesiones, y después tú deberás tomar la iniciativa y hacer los ejercicios que te propongo. En esta práctica necesitarás usar los comandos Nest[f,x,n] y NestList[f,x,n]. En la ayuda de Mathematica encontrarás información detallada sobre ellos.

La sucesión  x[n + 1] = (i^x)[n] con  x[1] = i

g[z_] := 
      I^z

lista = N[NestList[g, I, 29]]

puntos = Transpose[{Re[lista], Im[lista]}] ;

Show[Graphics[{PointSize[ .015], Point/@puntos}], 
        Axes -> True, PlotRange -> All, AspectRatio -> 1];

Show[Graphics[{Line[puntos], {PointSize[ .015], Point/@puntos}}], 
        Axes -> True, PlotRange -> All, AspectRatio -> 1];

colores = 
      Flatten[Table[{Hue[0], Hue[ .33], Hue[ .66]}, {k, 1, 10}]]   ;

graf1 = 
      Show[Graphics[{
            Line[puntos], {PointSize[ .015], 
              Transpose[{colores, Point/@puntos}]}}], Axes -> True, 
        PlotRange -> All, AspectRatio -> 1];

El límite de la sucesión debe ser un punto fijo de la función g.

α = z/.FindRoot[
          g[z] - z, {z, Nest[g, I, 5]}]  (* 
          calculamos el límite de la sucesión *)

g[α]

Observa que si z está cerca de α entonces g[z]-g[α]=g[z]-α es aproximadamente igual a g'[α](z-α). Es decir, sustituir z por g[z]  en z-α tiene aproximadamente el mismo efecto que multiplicar z-a por g'[α]. Definamos:

e[n_] := N[Nest[g, I, n]] -  α

Para representar los puntos e[n] basta trasladar el origen en la gráfica anterior.

Show[graf1, AxesOrigin -> {Re[α], Im[α]}];

Según lo antes dicho, tenemos que \(TraditionalForm
      \`e[n + 1] ≃ \(g'\)[α] e[n] = 
        \((\(-0.5664173302856166`\) + 0.6884532271076301`\ i)\) 
          e[n]\). Es decir e[n + 1] se obtiene:
1º) Girando e[n] un ángulo (en grados) igual a:

Arg[g'[α]]*180/Pi

Deducimos que cada término está girado aproximadamente unos 129 grados respecto del anterior (con centro de giro en α). Eso explica que la gráfica aparezca como una triple espiral.
2º) Multiplicando el módulo de e[n] por:

Abs[g'[α]]

Deducimos que \(TraditionalForm
      \`|\ e[n + 1]\ |\( ≃ 0.891514\) | e[n] |\) esto es la distancia al límite decrece por el factor 0.891514, lo que nos dice que la sucesión se aproxima bastante rápidamente a su límite.

Abs[e[100]]

La sucesión  x[n + 1] = (a^x)[n] con  x[1] = z   (a,z ∈ ℂ)

Clear["Global`*"]

potencia[a_][z_] := a^z

Cuando la sucesión es convergente su límite, que no depende del valor inicial (Subscript[x, 1]), viene dado por:

\(\(puntofijopotencia[a_] := 
      z /. FindRoot[a^z == z, {z, Nest[potencia[a], 1.  + 1. \ I, 4]}, 
          
	MaxIterations -> 30]\ \)\)

Hemos visto antes que el comportamiento de la sucesión depende del número:

H[a_] := potencia[a]'[puntofijopotencia[a]]

Podemos elegir a para conseguir un comportamiento determinado aunque hay que tener en cuenta que, si bien el posible límite de la sucesión solamente depende del valor de a, la convergencia puede depender del valor inicial. Si  Abs[H[a]] < 1 y elegimos x[1] próximo a puntofijopotenccia[a] entonces la sucesión converge a dicho número el cual se dice que es un punto fijo atractivo. Si  Abs[H[a]] > 1 y elegimos x[1] próximo a puntofijopotencia[a] pero distinto de puntofijopotencia[a] entonces la sucesión no converge. En este caso se dice que puntofijopotencia[a] es un punto fijo repelente. Hasta aquí llego yo y ahora debes seguir tú.

Ejercicios

1 Define una función gráfica, "puntossucesion[a_, z_, n_, opts___]",  que al ejecutarla muestre en pantalla los primeros n términos de la sucesión  x[n+1]=a^x[n] con x[1]=z como puntos del plano unidos por segmentos. Elige un tamaño adecuado para los puntos y representa cada tres puntos consecutivos en colores rojo, verde y azul como hemos hecho antes. Centra el origen de coordenadas en el posible límite de la sucesión y pásale las opciones gráficas a la función que defines. 
Sugerencias. Puede ser útil que primero definas una lista "puntos[a_,z_,n_]" a la que puedas aplicar las primitivas gráficas Point y Line.

2 a) Considera la siguiente lista de números complejos.

valoresa = 
      Flatten[Table[x  +  y I, {x, 0. , 3, 0.25}, {y,  .5, 2.5, 0.25}]];

Construye a partir de ella una lista, "puntosfijovaloresa", cuyos elementos sean listas de la forma 
				{a, puntofijopotencia[a], Abs[H[a]], Arg[H[a]]*180/N[π]} 
donde a∈valoresa. 
Sugerencias. Todo lo que tienes que hacer es "lanzar" una función, es fácil imaginar cuál, para que actúe sobre los elementos de la lista "valoresa". Recuerda el uso de #  y & para sustituir las variables así como el comando /@.
b) Selecciona los elementos de la lista "puntosfijovaloresa" para los que se verifica que Abs[H[a]]<.5. Estos valores de a son puntos fijos atractivos. Elije uno de ellos y un valor de z más o menos próximo a él para representar con el comando "puntossucesion[a_, z_, n_, opts___]"  los primeros 9 términos de la sucesión correspondiente.
Sugerencia. Usa el comando "Select[lista,criteriodeseleccion]" (consulta si es necesario la ayuda).
c) Selecciona los elementos de la lista "puntosfijovaloresa" para los que se verifica que Abs[H[a]]>1.3. Estos valores de a son puntos fijos repelentes. Elije uno de ellos y un valor de z más o menos próximo a él para representar con el comando "puntossucesion[a_, z_, n_, opts___]"  los primeros 9 términos de la sucesión correspondiente.
d) Hemos visto que Arg[H[a]] indica el ángulo (en radianes) que cada término de la sucesión está girado respecto del término anterior (con centro de giro en puntofijopotencia[a]). Selecciona los elementos de la lista "puntosfijovaloresa" para los que se verifica que 118<Arg[H[a]]<122. Elige dos de ellos, uno que sea un punto fijo atractivo y otro que sea un punto fijo repelente y elige valores adecuados de z para representar en cada caso los primeros 30 términos de la sucesión correspondiente.