Aplicaciones de la integral definida

Práctica de Cálculo, E.U.A.T,

Esta práctica muestra cómo calcular algunas áreas y volúmenes utilizando integrales. En cada caso daremos fórmulas para calcular el área o el volumen del que se trate; la justificación de estas fórmulas se ha visto (o se verá pronto) en la clase de teoría.

Para dibujar algunas de las funciones que aparecen en la práctica usaremos algunas órdenes gráficas nuevas: FilledPlot y ParametricPlot3D. Estas órdenes no son necesarias para los cálculos que haremos, pero son muy útiles para mostrar gráficamente superficies o volúmenes.

En algunas de las órdenes siguientes no se muestra el dibujo de salida, pero podéis verlo ejecutando las órdenes en Mathematica.

Área  de una región plana limitada por dos curvas

Área  entre una función y el eje horizontal

Como sabéis, el área entre la gráfica de una función positiva y el eje horizontal en una cierta región es la integral indefinida de dicha función en esa región. Si la función no es siempre positiva, la integral indefinida cuenta el área "con signo": positiva si queda por encima del eje y negativa si queda por debajo. Entonces, para calcular el área entre la gráfica de una función y el eje horizontal lo que hacemos es calcular la integral del valor absoluto de dicha función.

El área entre la gráfica de una función y el eje horizontal en un intervalo es la integral del valor absoluto de la función en ese intervalo.

Por ejemplo: calculemos el área bajo la siguiente función en el intervalo [1,2]:

f[x_] := x^2  -  1/2

NIntegrate[Abs[f[x]], {x, 1, 2}]

Supongamos que queremos calcular el área entre la siguiente función y el eje horizontal, pero sólo en el trozo en que la función es positiva:

f[x_] := x^3 - 3  x^2 + 1;
Plot[f[x], {x, -1, 3}];

Primero tenemos que saber en qué intervalo es positiva; para eso podemos hallar los puntos de corte con NSolve:

corte = NSolve[f[x] == 0, x]

Vemos que nos interesa la integral entre el primer y el segundo corte:

a = x /. corte[[1]]
b = x /. corte[[2]]

Podemos sombrear el área que se quiere calcular:

<< Graphics`FilledPlot`
FilledPlot[f[x], {x, a, b}];

Su valor es:

NIntegrate[f[x], {x, a, b}]

(Aquí no hace falta el valor absoluto porque la función es positiva en este intervalo)

Si queremos hallar el área entre la misma función y el eje horizontal, pero ahora entre el primer corte y el segundo, podemos hacer lo mismo cambiando los extremos:

c = x /. corte[[3]]

FilledPlot[f[x], {x, a, c}]

NIntegrate[f[x], {x, a, b}]  - NIntegrate[f[x], {x, b, c}]

Área   entre dos funciones

Calcular el área del trozo que queda entre las gráficas de dos funciones f y g es lo mismo que calcular el área entre la función f-g y el eje horizontal, así, que podemos calcularla como la integral indefinida del valor absoluto de f-g.

Por ejemplo, calculemos el área del trozo que queda entre estas dos funciones entre sus dos cortes:

f[x_] := Cos[x];   
g[x_] := x^2 - x - 1;   
Plot[{f[x], g[x]}, {x, -3, 3}, 
        PlotStyle -> {{RGBColor[1, 0, 0]}, {RGBColor[0, 0, 
                1]}}];

Primero calculamos los cortes (esta vez necesitamos usar FindRoot):

sol1 = FindRoot[f[x] == g[x], {x, 0}]

a = x /. sol1[[1]]

sol2 = FindRoot[f[x] == g[x], {x, 1}]

b = x /. sol2[[1]]

NIntegrate[f[x] - g[x], {x, a, b}]

El trozo del que hemos calculado el área es éste:

FilledPlot[{f[x], g[x]}, {x, a, b}];

Longitud de una curva dada como gráfica de una función

Podemos calcular la longitud de la curva que resulta al dibujar la gráfica de la función f de [a,b] en R usando la siguiente fórmula (que no justificaremos aquí):

longitud de la gráfica = (∫_a^b)((Sqrt[1 + (((f' (x)))^2)])) dx

Un ejemplo:

f[x_] := Tan[x]

      
Plot[f[x], {x, -1.3, 1.3}];
longitud = 
      NIntegrate[Sqrt[1 + (f'[x])^2], {x, -1.3, 1.3}]

Área   de una superficie de revolución

Girando en torno a OX

Dada una función positiva f definida en [a,b], pensamos en la superficie que se genera si giramos esa función una vuelta completa alrededor del eje horizontal. El área de la superficie que queda viene dada por la fórmula siguiente:

área al girar en torno a OX = 2π (∫_a^b)f(x) (Sqrt[1 + (((f' (x)))^2)]) dx

f[x_] := 
        1 + 1/(5.6 - x) + 1/2 Cos[x];
Plot[f[x], {x, 0, 5}, PlotRange -> {0, 3}, 
        AspectRatio -> Automatic];
ParametricPlot3D[{x, f[x] Cos[u], f[x] Sin[u]}, {x, 0, 
          5}, {u, -Pi/2, 3 Pi/2}];

El área se obtiene usando la fórmula anterior:

area = 
      2*Pi*NIntegrate[
          f[x] Sqrt[1 + (f'[x])^2], {x, 0, 5}]

Girando en torno a OY

Si ahora tenemos una función f definida en [a,b] con a>0 (ahora no hace falta que f sea positiva), podemos girarla en torno al eje OY y generar así una superficie. Su área viene dada por:

área al girar en torno a OY = 2π (∫_a^b)x (Sqrt[1 + (((f' (x)))^2)]) dx

Un ejemplo (media esfera):

f[x_] := -Sqrt[1 - x^2];
Plot[f[x], {x, 0, 1}, PlotRange -> {0, -1}, 
        AspectRatio -> Automatic];
ParametricPlot3D[{x Cos[u], x Sin[u], f[x]}, {x, 0, 
          1}, {u, -Pi/2, 3 Pi/2}];

area = 
      2*Pi*Integrate[x Sqrt[1 + (f'[x])^2], {x, 0, 1}]

(Observad que en este caso particular hemos podido calcular la integral exacta usando Integrate).

Volumen de un sólido de revolución

Método de discos

Dada una función positiva  f definida en [a,b], generamos un sólido de revolución girando 360º la región que queda bajo la gráfica de f entre las abscisas a y b en torno al eje OX. El volumen de la figura así construida puede calcularse usando la siguiente fórmula, llamada fórmula de los discos:

volumen al girar en torno a OX = π (∫_a^b)(((f (x)))^2) dx

Un ejemplo:

f[x_] := 
        1 + 1/(5.6 - x) + 1/2 Cos[x];
FilledPlot[f[x], {x, 0, 5}, PlotRange -> {0, 3}, 
        AspectRatio -> Automatic];
ParametricPlot3D[{{x, f[x] Cos[u], f[x] Sin[u]}, {5, 
            f[5] x/5 Cos[u], f[5] x/5  Sin[u]}}, {x, 0, 5}, {u, 0, 
          2 Pi}];

Su volumen es:

volumen = Pi*NIntegrate[(f[x])^2, {x, 0, 5}]

La fórmula se llama de los discos porque se obtiene "sumando" las áreas de los discos que genera cada línea vertical de la región como vemos en la siguiente ilustración. (Recordamos aquí que una integral es en esencia una "suma infinita",por ello la "suma" de todas las áreas de cada disco, π (((radio))^2) = π (((f(x)))^2), da lugar a la integral anterior).

Lo siguiente es sólo para que se vea esta idea:

ParametricPlot3D[{{x, 0, f[x] u/(2  Pi)}, {2, f[2] x/5 Cos[u], 
            f[2] x/5  Sin[u]}, {4, f[4] x/5 Cos[u], f[4] x/5  Sin[u]}}, {x, 
          0, 5}, {u, 0, 2  Pi}, AspectRatio -> Automatic, 
        ViewPoint -> {3.6, -3.6, 1}, 
        PlotRange -> All];

Método de capas

Dada una función f definida en [a,b] con a>0, generamos un sólido girando como antes la región entre la gráfica de f y el eje horizontal, esta vez alrededor del eje OY. El volumen del cuerpo que resulta está dado por la siguiente fórmula:

volumen al girar en torno a OY = 2π (∫_a^b)x f(x) dx

Si f es negativa en algún punto hace falta poner el valor absoluto de f en la fórmula anterior en lugar de f para no contar como negativo el volumen que queda por debajo del eje horizontal.

f[x_] := 1/4 + Sqrt[1/4 - (x - 1)^2]; 
  
FilledPlot[f[x], {x, 0.5, 1.5}, PlotRange -> {0, 1}, 
        AspectRatio -> Automatic];
ParametricPlot3D[{{x Cos[u], x Sin[u], f[x]}, {0.5 Cos[u], 
            0.5 Sin[u], (x - 0.5) f[1.5]}, {1.5  Cos[u], 
            1.5  Sin[u], (x - 0.5) f[1.5]}}, {x, 0.5, 1.5}, {u, 0, 
          2 Pi}, AspectRatio -> Automatic, 
        ViewPoint -> {0.5, -3, 2}, 
        PlotRange -> All];

El volumen es:

volumen = 2*Pi*NIntegrate[x f[x], {x, 0.5, 1.5}]

La fórmula se llama de capas porque se obtiene "sumando" las áreas de las capas que genera cada línea vertical de la región (recordamos aquí que una integral es en esencia una "suma infinita", así que la "suma" de todas las áreas de cada tubo, 2π (base)×(altura) = 2π x f(x), da lugar a la integral). El siguiente dibujo muestra esto:

ParametricPlot3D[{{x, 0, f[x] u/(2  Pi)}, {0.51  Cos[u], 
            0.51  Sin[u], (x - 0.5) f[0.51]}, {0.9  Cos[u], 
            0.9  Sin[u], (x - 0.5) f[0.9]}}, {x, 0.5, 1.5}, {u, 0, 
          2 Pi}, AspectRatio -> Automatic, 
        ViewPoint -> {-1.069, -2.776, 2.5}, 
        PlotRange -> All];

Ejercicios

1- Calcular el área de la región del plano limitada por las curvas siguientes entre las abscisas x=-2 y x=2:
	y = x sen(x+2),  y=4 cos(x)

2- Calcular la longitud del arco de la curva f(x) = 6 log(x) + 7 (Sqrt[(x^3)]) entre los puntos de abscisas x=1 y x=3.

3- Halla el área de la región del plano entre la curva
	y = 6 - 3x - (x^2)
	y la recta x+y-3=0.

4- Halla el volumen del sólido que resulta al girar el área bajo la parte positiva de la gráfica de y = -(x^2) + 5 en torno al eje OX.

5- Halla el área de la superficie que resulta al girar la curva del ejercicio anterior en torno al eje OX.

6- Halla el volumen del cuerpo que queda al girar la región bajo la gráfica de la función coseno entre 0 y π/2, primero en torno al eje OX y luego en torno al eje OY.

7- Con la función anterior, calcula el área de la superficie resultante al girar en torno a los dos ejes.

8- Calcula una fórmula explícita para el volumen de una esfera.

9- Encuentra una fórmula que dé el volumen de un cono de revolución.

10- Con los comandos aqui expuestos realiza los ejercicios del 20 al 29 de la relación de ejercicios de teoría.