Práctica 9 (Cálculo)

Integral doble

Clear["Global`*"]

Integral doble en dominios rectangulares.

Consideramos una función f:D⟶ℝ integrable Riemann, donde D=[a,b]×[c,d] es un dominio rectangular. La integral de f en el dominio D se calcula mediante el comando Integrate. En el siguiente ejemplo se integra la función f en el dominio [1,7]×[2,3], es decir x∈[1,7], y∈[2,3].

f[x_, y_] := 2  x + 7  y + 2

Plot3D[f[x, y], {x, 1, 7}, {y, 2, 3}]

Integrate[f[x, y], {x, 1, 7}, {y, 2, 3}]

Integrate[f[x, y], {y, 2, 3}, {x, 1, 7}]

Al efectuar las integrales sin emplear el ordenador, se usa el Teorema de Fubini y se efectua la integral en una de las variables, y luego se integra en la otra variable. Este proceso también se puede realizar con Mathematica.

Primero calculamos la integral de f entre x=1 y x=7. Esta integral depende de y, la notamos F[y]. Luego calculamos la integral de esta función entre y=2 e y=3.

F[y_] = Integrate[f[x, y], {x, 1, 7}]

Integrate[F[y], {y, 2, 3}]

Ahora calculamos primero la integral entre y=2 e y=3, que llamamos G[x]. Y a continuación calculamos la integral de esta función entre x=1 y x=7. Observamos que se obtiene el mismo resultado.

G[x_] = Integrate[f[x, y], {y, 2, 3}]

Integrate[G[x], {x, 1, 7}]

Para calcular una aproximación numérica de una integral doble, podemos usar la orden NIntegrate.

g[x_, y_] := Sin[x*Sin[y]]
Integrate[g[x, y], {x, 1, 7}, {y, 2, 3}]
NIntegrate[g[x, y], {x, 1, 7}, {y, 2, 3}]

Ejercicio: Calcule la integral de la función f(x,y)=x^2*y^3+x en el dominio [2,5]×[3,7].

Ejercicio: Calcule la integral de la función g(x,y)=sen(x*cos(y^2)) en el dominio [-2,2]×[-5,7].

Representación de regiones regulares. Integrales en dichas regiones.

Dominios tipo I.

Los dominios de la forma R=\(\(\({\((x, 
            y)\) ∈ \(ℝ\^2\  : \ \ a ≤ x ≤ b\), \ \ α \((x)\) ≤ 
          y ≤ β \((x)\)}\)\(\ \)\)\)se dicen dominios regulares de tipo I. La coordenada x varía entre dos números fijos a y b, y, dado un valor de x, la coordenada y de los puntos (x , y), varía entre  α(x) y β(x).

Para representar gráficamente uno de estos dominios, dibujaremos la frontera de R. Para lo cual representamos las gráficas de las funciones α(x) y β(x). Como ejemplo consideramos el dominio R=\({\((x, 
            y)\) ∈ \(ℝ\^2\  : \ \ 1 ≤ x ≤ 2\), \ \ x - 2 ≤ 
          y ≤ \(-x^2\) + 5}\).

Plot[{x - 2, -x^2 + 5}, {x, 1, 2}]

Hemos dibujado parte de la frontera del dominio R. Para representar el dominio empleamos la orden FilledPlot que estudiamos en la práctica 7.

Needs["Graphics`FilledPlot`"];
FilledPlot[{x - 2, -x^2 + 5}, {x, 1, 2}]

Ejercicio: Represente la región E1=\(\(\({\((x, 
              y)\) ∈ \(ℝ\^2\  : \ \ 1 ≤ x ≤ 4\), \ \ \(-x^2\) + 5  x - 3 ≤ 
            y ≤ x^2 + 7}\)\(\ \)\(.\)\)\)

Supongamos que queremos calcular la integral de la función f(x,y)=x^2+x*y en el dominio R. Para calcular dicha integral debemos considerar los siguientes límites de integración.

\(∫\_D 
            f \((x, y)\) dx dy = ∫\_\(x = 1\)\%\(x = 2\)\((∫\_\(y = \ α \((x)\)\)\%\(y = \ β \((x)\)\)f \((x, 
                    y)\) dy)\) dx\)

Esta integral puede calcularse empleando las siguientes instrucciones de Mathematica, la primera emplea la orden Integrate, y la siguiente emplea la paleta BasicInput. Se comprueba que ambas instrucciones dan el mismo resultado.

Integrate[ 
      Integrate[x^2 + x*y, {y, x - 2, -x^2 + 5}], {x, 1, 2}]

(∫_1^2)(∫_(x - 2)^(-x^2 + 5))(x^2 + 
              x*y) \[DifferentialD]y \[DifferentialD]x

Ejercicio: Calcule la integral de la función x^2*y+2x*y en la región anterior E1=\(\(\({\((x, 
              y)\) ∈ \(ℝ\^2\  : \ \ 1 ≤ x ≤ 4\), \ \ \(-x^2\) + 5  x - 3 ≤ 
            y ≤ x^2 + 7}\)\(\ \)\(.\)\)\)

Dominios tipo II.

Los dominios de la forma S={(x, 
          y) ∈ (ℝ^2)  :   c ≤ 
            y ≤ d,   γ (y) ≤ 
        x ≤ δ (y)} se dicen dominios regulares de tipo II. Para dibujar la frontera de estos dominios debemos dibujar las rectas y=c, y=d, así como las gráficas de las curvas (dadas de forma implícita) x=γ(y), x=δ(y). Estas últimas gráficas se pueden representar con la orden ImplicitPlot.

Como ejemplo representamos el dominio \(S = {\((x, 
              y)\) ∈ \(ℝ\^2\  : \ \ \(-1\) ≤ y ≤ 2\), \ \ \(-\((1/2)\)\) y - 1 ≤ 
            x ≤ 4 - y^2}\).

Para representar este dominio usando ImplicitPlot, debemos especificar un intervalo para la variable x lo suficientemente grande como para representar completamente el dominio S. Una vez representado S, se puede ajustar el intervalo para x.

Needs["Graphics`ImplicitPlot`"]
A1 = 
      ImplicitPlot[
        x == -(1/2) y - 1, {x, -4, 
          4}]
B1 = 
      ImplicitPlot[
        x == 4 - y^2, {x, -4, 4}]
C1 = Plot[{-1, 2}, {x, -4, 4}]
Show[A1, B1, C1]

A la vista de la gráfica, podemos cambiar intervalo de definición de x

A2 = 
      ImplicitPlot[
        x == -(1/2) y - 1, {x, -2.5, 
          0}]
B2 = 
      ImplicitPlot[
        x == 4 - y^2, {x, -3, 4}]
C2 = Plot[{-1, 2}, {x, -2, 4}]
Show[A2, B2, C2]

Ejercicio: Represente la región E2=\(\(\({\((x, 
              y)\) ∈ \(ℝ\^2\  : \ \ 2 - \@\(\(-8\) + 6\ y - y\^2\) ≤ x ≤ 
                7 + \@\(\(-8\) + 6\ y - y\^2\)\), \ \ 2 ≤ 
            y ≤ 4}\)\(\ \)\(.\)\)\)

Si queremos calcular la integral de la función g(x,y)=x*cos(y) en el dominio S, debemos considerar los límites de integración que se muestran a continuación.

\(∫\_S 
            g \((x, y)\) dx dy = ∫\_\(y = \(-1\)\)\%\(y = 2\)\(∫\_\(x = \(-\((1/2)\)\) y - 1\)\%\(x = 4 - y^2\)g \((x, y)\) dx dy\)\)

Para efectuar la integral con Mathematica, podemos emplear alguna de las instrucciones siguientes.

Integrate[ 
      Integrate[x*Cos[y], {x, -(1/2) y - 1, 4 - y^2}] , {y, -1, 
        2}]

(∫_(-1)^2)(∫_(-(1/2) y - 1)^(4 - y^2))x*Cos[y] \[DifferentialD]x \[DifferentialD]y

Ejercicio: Calcule la integral de la función h(x,y)=x*y en la región del ejercicio anterior E2=\(\(\({\((x, 
              y)\) ∈ \(ℝ\^2\  : \ \ 2 - \@\(\(-8\) + 6\ y - y\^2\) ≤ x ≤ 
                7 + \@\(\(-8\) + 6\ y - y\^2\)\), \ \ 2 ≤ 
            y ≤ 4}\)\(\ \)\(.\)\)\)

Dominios tipo III.

Las regiones de tipo III son aquellas que pueden considerarse como de tipo I o como de tipo II. Por ejemplo, consideramos la región T={(x, 
          y) ∈ (ℝ^2) :(x-2)^2+(y-2)^2=3^2} que es un círculo de centro el punto (2,2) y radio 3. Esta región se puede representar como una región de tipo I (despejando y en función de x) o de tipo II (despejando x en función de y).

Podemos representar la frontera del dominio (es decir, la circunferencia) usando la orden ImplicitPlot.

ImplicitPlot[(x - 2)^2 + (y - 2)^2 == 3^2, {x, -5, 
        5}]

En ocasiones es preferible representar la circunferencia con la orden Circle, que dibuja una circunferencia dado su centro y su radio. La opción AspectRatio hace que Mathematica elija automáticamente la razón entre la altura y la anchura del dibujo, de forma que represente una circunferencia.

A = Graphics[Circle[{2, 2}, 3] ]
Show[A]
B = 
      Graphics[Circle[{2, 2}, 3] , 
        AspectRatio -> Automatic ]
Show[B]

Dominios compuestos.

También se pueden considerar regiones que se descomponen en un número finito de regiones de los tipos I, II o III vistas anteriormente.

Representamos ahora la región W delimitada superiormente por las curvas C1≡(x-2)^2+y^2=4, C2≡ 4-x=y^2, e inferiormente por la recta x=2 y.

C1 = 
      Graphics[Circle[{2, 0}, 2], 
        AspectRatio -> Automatic]
C2 = 
      ImplicitPlot[4 - x == y^2, {x, 0, 4}]
C3 = 
      ImplicitPlot[2  y == x, {x, 0, 4}]
Show[C1, C2, C3]

En el dibujo se observan dos regiones limitadas inferiormente por la recta 2y=x. De estas dos regiones, sólo una está limitada superiormente por las curvas C1 y C2.

Para integrar en muchos dominios, es necesario calcular los puntos de intersección de las curvas que determinan dicho dominio. Por ejemplo, en la región anterior, calculamos con la orden Solve el punto de intersección de C1≡(x-2)^2+y^2=4 con C2≡ 4-x=y^2.

Solve[{(x - 2)^2 + y^2 == 4, 4 - x == y^2}, {x, y}]

De los tres puntos de corte, sólo nos interesa el que está en la frontera de la región considerada, es decir (x, y) = (1, (Sqrt[3])).

Calculamos de forma similar la intersección de la recta 2y=x con la curva C1≡(x-2)^2+y^2=4.

Solve[{(x - 2)^2 + y^2 == 4, 2 y == x}, {x, y}]

De donde obtenemos el punto (0,0).

El tercer punto que vamos a calcular es el punto de corte de la recta 2y=x con la parábola C2≡4-x=y^2.

Solve[{2 y == x, 4 - x == y^2}, {x, y}]

Y obtenemos el punto de coordenada y positiva, (x,y)=(2 (-1 + (Sqrt[5])),  -1 + (Sqrt[5]))

Si quisiéramos representar la región empleando FilledPlot, debemos despejar y en función de x, y considerar los puntos de intersección hallados.

W1 = 
      FilledPlot[{x/2, (Sqrt[4 - (x - 2)^2])}, {x, 0, 
          1}]
W2 = 
      FilledPlot[{x/2, (Sqrt[4 - x])}, {x, 1, 
          2 (-1 + (Sqrt[5]))}]
Show[W1, W2]

La región W que hemos representado puede descomponerse como dos regiones de tipo I. Por tanto la integral de la función h(x,y)=2x*y^2-x en W se puede hallar sumando la integral de h en W1 mas la integral de h en W2.

\(∫\_W 
            h \((x, y)\) dx dy = ∫\_W1 
              h \((x, y)\) dx dy\  + \ ∫\_W2 h \((x, y)\) dx dy\)

Cada una de estas integrales se puede calcular poniendo los límites de integración adecuados, como se vió al estudiar los dominios tipo I. Las siguientes instrucciones calculan la integral en W1 y W2, y las suman para hallar la integral en W.

NIntegrate[ 
        Integrate[2  x*y^2 - x, {y, x/2, (Sqrt[4 - (x - 2)^2])}] , {x, 0, 
          1}]  +  
NIntegrate[ 
        Integrate[2  x*y^2 - x, {y, x/2, (Sqrt[4 - x])}] , {x, 1, 
          2 (-1 + (Sqrt[5]))}]

N[(∫_0^1)(∫_(x/2)^((Sqrt[4 - (x - 2)^2])))(2  x*y^2 - 
                  x) \[DifferentialD]y \[DifferentialD]x  +  (∫_1^(2 (-1 + (Sqrt[5]))))(∫_(x/2)^((Sqrt[4 - x])))(2  x*y^2 - x) \[DifferentialD]y \[DifferentialD]x ]

Ejercicio: Calcule la integral de la función t(x,y)=x^4+y^4+2 en el dominio W definido en esta sección.

Ejercicio: Represente el dominio acotado EC que se encuentra limitado por las rectas y=x, y=4x-2, y= - x+8.

Ejercicio: Calcule la integral de la función q(x,y)=x+2y en el dominio EC definido en el ejercicio anterior.

Representación de regiones mediante coordenadas polares.

Consideremos el dominio R1={(x, y) ϵ (ℝ^2)  :  
            x^2 + y^2 ≤ 1,  0 ≤ y ≤ x}. Las siguientes instrucciones permiten visualizar esta región.

G1 = 
      FilledPlot[Sqrt[1 - x^2], {x, Cos[Pi/4], 1}]
G2 = FilledPlot[x, {x, 0, Cos[Pi/4]}]
Show[G1, G2]

Recordamos la función que definía el cambio de coordenadas polares, esto es, F( ρ , φ )=( ρ*cos(φ) , ρ*sen(φ) ). La región R1 puede definirse en coordenadas polares como una región T1==\({\((ρ, φ)\) ϵ\ \(ℝ\^2\  : \ ρ ≤ 1\), \ 
        0 ≤ φ ≤ Pi\ /\ 4}\), ya que F(T1)=R1.

Vamos a representar la frontera de R1 usando coordenadas polares. Para ello vemos que la parte curva de la frontera de T1 la forman los puntos (ρ,φ) con ρ=1, y con 0≤φ≤Pi / 4. Así pues para estos puntos se tiene que x= ρ*cos(φ)=cos(φ), y= ρ*sen(φ)=sen(φ).

Dibujamos la parte curva de la frontera con la orden ParametricPlot, donde damos la coordenada x, así como la coordenada y, de los puntos a representar en función de φ.

ParametricPlot[{Cos[φ], Sin[φ]}, {φ, 0,  
        Pi/4}, AxesOrigin -> {0, 0}, 
      AspectRatio -> Automatic]

En este caso el valor de ρ es constantemente igual a 1. En casos más generales la frontera de una región se corresponderá con una curva dada en polares mediante una función ρ(φ).

Por ejemplo, supongamos que queremos representar los puntos que tienen radio ρ(φ)=2*sen(3φ). Es decir, puntos del plano x=2*sen(3φ)*cos(φ), y=2*sen(3φ)*sin(φ). Estos puntos se representan con la siguiente instrucción.

ParametricPlot[{2  Sin[3 φ]*Cos[φ], 
        2  Sin[3 φ]*Sin[φ]}, {φ, 0,  2*Pi}, 
      AspectRatio -> 1]

En ocasiones es conveniente usar otra notación. Por ejemplo el mismo gráfico anterior se puede representar mediante esta instrucción.

r[t_] := 2  Sin[3 t]
ParametricPlot[{r[t]*Cos[t], r[t]*Sin[t]}, {t, 0,  2*Pi}, 
      AspectRatio -> 1]

De igual forma representamos estas otras funciones.

ParametricPlot[{2*(1 + Cos[t])*Cos[t], 
        2*(1 + Cos[t])*Sin[t]}, {t, 0,  2*Pi}, 
      AspectRatio -> 1]

ParametricPlot[{(Sqrt[2*3^2*Cos[2 t]])*Cos[t], (Sqrt[2*3^2*Cos[2 t]])*
          Sin[t]}, {t, 0,  Pi/4}, AspectRatio -> 1]

Ejercicio: Represente la curva dada por la función en polares r(t)=3sin(t)*cos(t), para 0≤t≤2 Pi. Idem r(t)=4cos(t)sen^2(t) para 0≤t≤Pi