Práctica 8 (Cálculo)

(Segunda Parte)

Funciones de varias variables

Clear["Global`*"]

Plano tangente.

Dada una función de dos variables f(x,y), podemos definir la superficie formada por los puntos (x,y,z) que verifican que z=f(x,y). Esta superficie puede dibujarse usando la orden Plot3D vista anteriormente.

f[x_, y_] := Exp[-(x^2 + y^2)]
Plot3D[
      f[x, y], {x, -2, 2}, {y, -2, 2}]
G1 = 
      Plot3D[f[x, y], {x, -2, 2}, {y, -2, 2}, 
        ViewPoint -> {0, 1, - .1}]

Si f es diferenciable en un punto (a,b), podemos definir el plano tangente a la superficie z=f(x,y) en el punto (a,b) mediante la fórmula z=f(a,b)+(x-a)(∂(f/∂) x (a, b))+(y-b)(∂ (f/∂) y (a, b)). Así para la función f definida, se tiene que su plano tangente en el punto (0.1 , 0.1), se define como a continuación.

a = 0.1;
b = 0.1;
z = 
      f[a, b] + (x - 
              a)*(D[f[x, y], x] /. {x -> a, y -> b}) + (y - 
              b)*(D[f[x, y], y] /. {x -> a, 
                y -> b})
Expand[z]

Representamos conjuntamente la función f y el plano tangente definido.

G2 = 
      Plot3D[z, {x, -1, 1}, {y, -1, 1}, 
        ViewPoint -> {0, 1, -0.1}]

Show[G1, G2]

Ejercicio: Dada la función g(x,y)=-x^2-y^2+x, halle el plano tangente a la superfice z=g(x,y)  en el punto (0,0).

Ejercicio: Dada la función h(x,y)=-x^2-y^2+x+y, halle el plano tangente en el punto x=0.5, y=0.5. Compruebe que el plano tangente es constante (paralelo al plano z=0). Dibuje las curvas de nivel de la función h en un dominio que contenga al punto citado (x,y)=(0.5,0.5).

Puntos críticos de una función de varias variables.

Dada una función f(x,y), su puntos críticos son aquellos puntos en los que la función es diferenciable y todas las parciales se anulan. Por ejemplo, comprobamos que la función h(x,y)= - x^2-y^2+x+y tiene un punto crítico en (x,y)=(0.5,0.5). En primer lugar vemos que la función h es diferenciable, ya que es un polinomio, se pueden calcular sus parciales, y las parciales son continuas. En segundo lugar, calculamos sus derivadas parciales.

h[x_, y_] := -x^2 - y^2 + x + y
D[h[x, y], x]
D[h[x, y], y]

Y evaluamos en el punto (x,y)=(0.5,0.5).

D[h[x, y], x] /. {x -> 0.5, 
        y -> 0.5}
D[h[x, y], y] /. {x -> 0.5, y -> 0.5}

De igual forma, comprobamos que el punto (x,y)=(-1,0) es un punto crítico de la función t que se define.

t[x_, y_] := x^3*y + y^3*x + y
D[t[x, y], x] /. {x -> -1, 
        y -> 0}
D[t[x, y], y] /. {x -> -1, y -> 0}

Nos planteamos ahora el problema de encontrar los puntos críticos de una función diferenciable. Para lo cual debemos hallar puntos (x,y) que verifiquen que las parciales en esos puntos valgan cero. Es decir debemos resolver el sistema
∂ (f/∂) x=0 , ∂ (f/∂) y=0.

f[x_, y_] := 3  x^2 + 2  y^2 + x*y + 2*x + 1
Solve[{D[f[x, y], x] == 0, D[f[x, y], y] == 0}, {x, 
        y}]

Ejercicio: Compruebe que el punto (x,y)=((-1 + (Sqrt[5]))/2 ,  0) es un punto crítico de la función g(x,y)=e^(1-x^2-y^2)*(1+x^2+y^2+2*x). (Use la orden Simplify para simplificar los resultados)

Ejercicio: Halle los puntos críticos de la función w(x,y)=-x^3*y^2+4 x-ln(y^2).

Extremos relativos. (Condición necesaria)

Sabemos que para que una función f tenga en el punto a un extremo relativo, es necesario que f tenga en a un punto crítico. Es decir, los extremos relativos de la función f se encuentran entre los puntos críticos de f. Veamos un ejemplo particular, primero definimos f, y hallamos los puntos críticos.

f[x_, y_] := (x^4 + y^4)*
        Exp[(-(x^2 + y^2)/3)]
Sol = 
      Solve[{D[f[x, y], x] == 0, D[f[x, y], y] == 0}, {x, 
          y}]

Obtenemos 7 puntos críticos distintos, pero no todos son máximos o mínimos relativos. En concreto, hay cuatro máximos, cuatro puntos de silla y un mínimo, como puede verse en la gráfica. Como hemos dicho, entre los puntos críticos de la función se encuentran sus extremos relativos; aunque aparecen también puntos críticos que no son extremos relativos.

Plot3D[f[x, y], {x, -4, 4}, {y, -4, 4}, 
      PlotPoints -> 40]
ContourPlot[f[x, y], {x, -4, 4}, {y, -4, 4}, 
      PlotPoints -> 40]

Extremos relativos. (Condición suficiente)

Hemos visto, en el ejemplo anterior que el hecho de que un punto sea crítico no significa que sea extremo relativo. Es decir, ser punto crítico no es suficiente para ser extremo. Veamos unos ejemplos más, para lo que definimos las funciones f1, f2 y f3.

f1[x_, y_] := x^2 + y^2
f2[x_, y_] := x^2 - y^2
f3[x_, y_] := -x^2 - y^2

Estas tres funciones tienen un punto crítico en el punto (x,y)=(0,0), pero f1 tiene en esepunto un mínimo, f2 tiene un punto de silla y f3 tiene un máximo. Lo comprobamos viendo sus gráficas.

Plot3D[f1[x, y], {x, -2, 2}, {y, -2, 2}]

Plot3D[f2[x, y], {x, -2, 2}, {y, -2, 2}]

Plot3D[f3[x, y], {x, -2, 2}, {y, -2, 2}]

Como se vió en teoría (condición suficiente), para determinar si en un punto hay un máximo, un mínimo, o un punto de silla hay que estudiar la matriz hessiana de la aplicación en dicho punto. Por ejemplo, para la función f1 obtenemos su matriz hessiana, que tiene dos filas y dos columnas, y la evaluamos en el punto (0,0).

mhessiana1 = {{D[f1[x, y], {x, 2}], 
          D[f1[x, y], x, y]}, {D[f1[x, y], y, x], 
          D[f1[x, y], {y, 2}]}}
M1 = 
      mhessiana1 /. {x -> 0, y -> 0}
MatrixForm[M1]

Det[M1]

M1[[1, 1]]

Como el determinante de la matriz hessiana es positivo, y el primer elemento es positivo, deducimos (ya que la función tiene m=2 variables) que la función f1 tiene un mínimo relativo en el punto (0,0).
De forma similar para f2, hallamos su matriz hessiana en el punto crítico.

mhessiana2 = {{D[f2[x, y], {x, 2}], 
          D[f2[x, y], x, y]}, {D[f2[x, y], y, x], 
          D[f2[x, y], {y, 2}]}}
M2 = 
      mhessiana2 /. {x -> 0, y -> 0}
MatrixForm[M2]

Det[M2]

M2[[1, 1]]

Como el determinante de la matriz hessiana es negativo, se puede deducir que en el punto (0,0) no hay un extremo local, sino un punto de silla (es decir, ni máximo, ni mínimo local).
Para la función f3, su matriz hessiana en el punto (0,0) es la que se calcula a continuación.

mhessiana3 = {{D[f3[x, y], {x, 2}], 
          D[f3[x, y], x, y]}, {D[f3[x, y], y, x], 
          D[f3[x, y], {y, 2}]}}
M3 = 
      mhessiana3 /. {x -> 0, y -> 0}
MatrixForm[M3]

Det[M3]

M3[[1, 1]]

En este caso, el determinante de la matriz hessiana es positivo, y el primer elemento de la matriz es negativo, por lo tanto, en el punto (0,0) hay un máximo relativo.

Ejercicio: Halle y clasifique los puntos críticos de la función f(x,y)=x+x*y-x^2*y, así como de la función g(x,y)=x^2-6 x y+3y^2-6x+3y

Extremos condicionados. Método de Lagrange. (Condición necesaria)

Nos planteamos ahora el problema de hallar el máximo (o el mínimo) de una función f(x,y) sujeto a unas restricciones g1(x,y)=0, g2(x,y)=0. Sabemos que para que un punto a=(a1,a2,..) sea extremo de f sujeto a las restricciones dadas por g1, g2 es necesario que el punto a sea punto crítico de la función L=f-λ1 g1-λ2 g2 .

Como ejemplo, vamos a hallar los posibles puntos críticos de la función f(x,y)=3x^2+2x*y-2*y^2, entre los puntos que verifican la restricción x^2+y^2=1. Comenzamos definiendo la función y dibujando la gráfica.

f[x_, y_] := 3  x^2 + 2  x*y - 2*y^2
A = 
      Plot3D[f[x, y], {x, -1, 1}, {y, -1, 1}, 
        Mesh -> False]

A continuación, dibujamos la función restringiendola al conjunto x^2+y^2=1. La instrucción ParametricPlot3D dibuja una función donde las tres componentes (x,y,z) dependen de un mismo parámetro. Se han empleado coordenadas polares, y así x(t)= Cos[t], y(t)= Sin[t], z(t)=f(x,y)=f (Cos[t],Sin[t]).

B = 
      ParametricPlot3D[{Cos[t], Sin[t], f[Cos[t], Sin[t]], 
          RGBColor[1, 0, 0]}, {t, 0, 2  Pi}, 
        AxesLabel -> {"X", "Y", "Z"}]

Observando la gráfica, podemos esperar dos máximos relativos, y dos mínimos relativos

Dibujamos ahora las dos gráficas conjuntamente, y observamos la restricción que consideramos y la función f.

Show[A, B]

Para calcular los extremos de f restringidos a x^2+y^2=1, mediante el método de los multiplicadores de Lagrange, expresamos la restricción en la forma g(x,y) =0.

g[x_, y_] :=  x^2 + y^2 - 1

Y definimos la función L de la siguiente manera.

L[x_, y_, λ_] := f[x, y] - λ*g[x, y]

Buscamos los puntos críticos de L, empleando la orden Solve, y luego hallamos una aproximación numérica.

PCriticos = 
      Solve[{D[L[x, y, λ], x] == 0, 
          D[L[x, y, λ], y] == 0, 
          D[L[x, y, λ], λ] == 0}, {x, 
          y, λ}]

N[PCriticos]

A la vista de la gráfica debemos esperar que el primer y segundo puntos críticos sean mínimos relativos, y el tercero y el cuarto sean máximos relativos.

Ejercicio: Halle los extremos relativos de la función f(x,y)=x^2+y^2-2*x restringida a la condición x=y+1.

Extremos condicionados. Método de Lagrange. (Condición suficiente)

Como ejemplo vamos a estudiar si cada uno de los puntos críticos de la sección anterior es máximo condicionado, mínimo condicionado o no es extremo. Para ello emplearemos la condición suficiente para el método de Lagrange vista en clase. Por lo cual necesitaremos una base de la aplicación lineal dada por la diferencial de g.

f[x_, y_] := 3  x^2 + 2  x*y - 2*y^2
g[x_, y_] :=  x^2 + y^2 - 1

dg[x_, y_] := {D[g[x, y], x], D[g[x, y], y]}

El vector PCriticos, definido en la sección anterior, contiene los cuatro puntos críticos de la función L. Podemos hacer referencia al primero de ellos mediante la primera componente del vector.

PCriticos[[1]]

Y calcular la diferencial de g en dicho punto.

dg1 = dg[x, y] /. PCriticos[[1]]

Para calcular una base del núcleo de la aplicación dg1, usamos la orden NullSpace.

nucleo1 = NullSpace[{dg1}][[1]]

La siguiente orden comprueba que el vector hallado está en el núcleo de la aplicación dg1.

N[    dg1 . nucleo1   ]

Calculamos ahora el hessiano en el punto crítico.

mhessiana1 = {{D[L[x, y, λ], {x, 2}], 
            D[L[x, y, λ], x, y]}, {D[L[x, y, λ], y, x], 
            D[L[x, y, λ], {y, 2}]}} /. PCriticos[[1]]

Y multiplicamos el vector del nucleo, por la matriz hessiana, y de nuevo por el vector del núcleo. Como el resultado es positivo, concluimos que el primer punto crítico es un mínimo.

N[nucleo1 . mhessiana1 . nucleo1]

De igual forma, estudiamos el segundo punto crítico, que resulta ser otro mínimo relativo.

dg2 = dg[x, y] /. PCriticos[[2]];
nucleo2 = NullSpace[{dg2}][[1]];
mhessiana2 = {{D[L[x, y, λ], {x, 2}], 
              D[L[x, y, λ], x, y]}, {D[L[x, y, λ], y, x], 
              D[L[x, y, λ], {y, 2}]}} /. 
          PCriticos[[2]];
N[nucleo2 . mhessiana2 . nucleo2]

Realizamos el mismo proceso con el tercer punto crítico, que resulta ser un máximo relativo.

dg3 = dg[x, y] /. PCriticos[[3]];
nucleo3 = NullSpace[{dg3}][[1]];
mhessiana3 = {{D[L[x, y, λ], {x, 2}], 
              D[L[x, y, λ], x, y]}, {D[L[x, y, λ], y, x], 
              D[L[x, y, λ], {y, 2}]}} /. 
          PCriticos[[3]];
N[nucleo3 . mhessiana3 . nucleo3]

Y por último el cuarto punto crítico, otro máximo relativo.

dg4 = dg[x, y] /. PCriticos[[4]];
nucleo4 = NullSpace[{dg4}][[1]];
mhessiana4 = {{D[L[x, y, λ], {x, 2}], 
              D[L[x, y, λ], x, y]}, {D[L[x, y, λ], y, x], 
              D[L[x, y, λ], {y, 2}]}} /. 
          PCriticos[[4]];
N[nucleo4 . mhessiana4 . nucleo4]

Ejercicios

1- Calcule el plano tangente a la superficie z=f(x,y)=-cos((1/(x^2 + y^2 + 1))) en el punto (1,3).

2- Halle y estudie los puntos críticos de la función w(x,y)=27x^3+8y^3-xy , determinando los extremos locales de la función. (Descarte los puntos críticos complejos)

3- Estudie los puntos críticos de la función, que se dibujó anteriormente, f(x,y)=(x^4+y^4)*e^(-(x^2+y^2)/3) .

4- Halle los extremos relativos de la función f(x,y)=x^2+y^2 sujetos a la condición x^2/4+y^2/9=1 .

5- Halle los extremos absolutos de la función f(x,y)=x^2+2*x*y+y^2 en el dominio x^2+y^2≤9 .

6- Se quiere conectar un punto (x,y) a dos conducciones de forma que el coste sea mínimo. La primera conducción tiene la forma de la gráfica y=x^2+2, y la segunda tiene la forma y=x-1. Calcule el punto (x,y) sabiendo que el coste lineal a la primera conducción es de 1000 euros por unidad de longitud, y el coste a la segunda es de 2000 euros por unidad de longitud.