Práctica 7 (Cálculo)

Aplicaciones de la integral definida

Clear["Global`*"]

En la práctica anterior estudiamos órdenes para calcular la integral definida de una función en un intervalo. En esta práctica aplicaremos estas órdenes para calcular longitudes, áreas y volúmenes.

Área de la región plana comprendida entre una curva y el eje OX. (Área bajo una curva)

Como hemos visto en la práctica anterior, la integral definida se emplea para calcular áreas de regiones planas. Consideramos f:[a,b]⟶ℝ una función continua en [a,b] que verifica que f(x)≥0 para todo x∈[a,b]. Entonces el área de la región comprendida entre la función f(x), el eje OX y las rectas x=a y x=b se calcula mediante la siguiente integral definida S=(∫_a^b) f(x) dx.

Vamos a calcular el área comprendida entre la función f(x)=-x^2+x+6, el eje OX y las rectas x=1 y x=2. Comenzamos definiendo la función f, y dibujamos la gráfica de f en un intervalo mayor. (Llamamos a la gráfica A, para poder representar luego dos gráficos de forma conjunta).

f[x_] := -x^2 + x + 6
A = Plot[f[x], {x, 0, 4}];

Para ilustrar la región a la que vamos a calcular el área, la representaremos sombreada, para ello usaremos la orden FilledPlot, para lo cual necesitamos cargar antes un paquete con la instrucción Needs. Si no cargamos el paquete, Mathematica no sabrá ejecutar la orden FilledPlot.

Needs["Graphics`FilledPlot`"];
B=FilledPlot[f[x], {x, 1, 2},PlotRange->{0,7}];
Show[B,A]

Así pues, el area de la región sombreada se calcula usando la siguiente instrucción.

Integrate[f[x], {x, 1, 2}]

En la fórmula anterior hemos requerido que la función sea positiva. Supongamos ahora que queremos calcular el area de una función que cambia de signo.
Por ejemplo, supongamos que queremos calcular el area comprendida entre la función 2*sin(x) y el eje OX, entre x=0 y x=4Pi. Primero definiremos la función y representaremos la región a la que quermos calcular el área.

g[x_] := 2*Sin[x]

FilledPlot[g[x], {x, 0, 4  Pi}]

Integrate[g[x], {x, 0, 4  Pi}]

Si empleamos la fórmula anterior sin considerar que la función cambia de signo, vemos que el resultado no es correcto, ya que la integral nos ha dado 'el area con signo', es decir que el área de la parte que se encuentra bajo el eje OX se toma con signo negativo y la de la parte superior con signo positivo.

Así pues consideraremos cuatro intervalos, de forma que en cada intervalo la función sea positiva o negativa.

I1 = Integrate[g[x], {x, 0, Pi}]
I2 = Integrate[g[x], {x, Pi, 2  Pi}]
I3 = Integrate[g[x], {x, 2  Pi, 3  Pi}]
I4 = Integrate[g[x], {x, 3  Pi, 4  Pi}]

Y sumamos las áreas de las cuatro regiones teniendo en cuenta los signos. (Si f es una función negativa, la función -f es positiva y ∫-f(
                x) dx = -∫f(
                x) dx)

I1 - I2 + I3 - I4

El resultado anterior puede obtenerse considerando el valor absoluto de la función g. Veamos la gráfica de la función |g(x)|, valor absoluto de g(x), y a continuación el área bajo esta función.

FilledPlot[Abs[g[x]], {x, 0, 4 Pi}]

Integrate[Abs[g[x]], {x, 0, 4  Pi}]

\(Veamos\ ahora\ una\ función\ un\ poco\ más\ complicada, \ la\ función\ sin \((x\^2)\)\ considerada\ entre\ x = \(0\ y\ x = \(\(\@\(4  π\)\)\(.\)\)\)\)

Plot[Sin[x^2], {x, 0, Sqrt[4 Pi]}]

Representamos a continuación el área que queremos calcular.

FilledPlot[Sin[x^2], {x, 0, Sqrt[4 Pi]}]
FilledPlot[Abs[Sin[x^2]], {x, 0, Sqrt[4 Pi]}]

Vimos en la práctica casos en que la instrucción NIntegrate daba un resultado erroneo. Al calcular la siguiente integral definida, Mathematica nos avisa de que el resultado no tiene la precisión fijada por defecto, esto es, que puede que el resultado no sea correcto.

NIntegrate[Abs[Sin[x^2]], {x, 0, Sqrt[4 Pi]}]

Así pues, calculamos el área teniendo en cuenta intervalos en los que la función no cambie de signo. En este caso es relativamente sencillo obtener los puntos en los que la función sin((x^2)) cambia de signo.

J1 = NIntegrate[Sin[x^2], {x, 0, Sqrt[Pi]}]
J2 = 
      NIntegrate[
        Sin[x^2], {x, Sqrt[Pi], Sqrt[2 Pi]}]
J3 = 
      NIntegrate[
        Sin[x^2], {x, Sqrt[2  Pi], Sqrt[3 Pi]}]
J4 = NIntegrate[Sin[x^2], {x, Sqrt[3  Pi], Sqrt[4 Pi]}]

Y con las integrales definidas que acabamos de calcular obtenemos el área pedida.

J1 - J2 + J3 - J4

En algunos caso no es fácil las raíces de la función para calcular los intervalos en los que la función es positiva o negativa. Por ejemplo, queremos calcular el área que delimitan la función -(x^2) + 4  x - 1 y el eje OX.

Plot[-(x^2) + 4  x - 1, {x, 0, 4}]

Para calcular las raíces de esta función, empleamos las instrucciones que vimos en la práctica 5.

Solve[-(x^2) + 4  x - 1 == 0, x]

Con estos valores ya tenemos los extremos del intervalo en el que calculamos la integral definida.

Integrate[-(x^2) + 4  x - 1, {x, 2 - Sqrt[3], 
        2 + Sqrt[3]}]

Ejercicio: Calcule el area de la región determinada por la función y=-x^2+4*ln(x)+10 y la recta y=0.

Ejercicio: Calcule el area del círculo de radio r. (Considere la circunferencia de radio r, dada por x^2+y^2=r^2. Nótese que r es positivo, y por tanto en el resultado se tiene que Sign[r]=1)

Area entre dos curvas.

La integral definida también sirve para calcular el área que delimitan dos funciones. Si f y g son dos funciones f, g:[a,b]⟶ℝ continuas con f(x)≥g(x) para todo el dominio x∈[a,b], entonces el área de la región limitada por la gráfica de las funciones f y g y las rectas x=a y x=b se calcula como S=(∫_a^b)(f(x) - 
              g(x)) dx.

Como ejemplo, consideramos dos parábolas, y queremos calcular el área de la region que se encuentra entre las dos parábolas.

G1 = Plot[{x^2 + 4  x + 6, -x^2 + 8}, {x, -5, 5}]

Para calcular el área debemos hallar los puntos donde se cortan las parábolas. Con estos puntos podemos determinar la región a la que queremos calcular el área.

Solve[x^2 + 4  x + 6 == -x^2 + 8, x]

G2 = 
      FilledPlot[{x^2 + 4  x + 6, -x^2 + 
            8}, {x, -1 - (Sqrt[2]), -1 + (Sqrt[2])}]

Show[G1, G2]

La siguiente instrucción nos da el área exacta de la región que hemos descrito.

Integrate[(-x^2 + 8) - (x^2 + 4  x + 6), {x, -1 - 
          Sqrt[2], -1 + Sqrt[2]}]

Ejercicio: Calcule el area de la región determinada por la función y=sin(x) y la función x^2-4x+4

Longitud de una curva.

Para calcular la longitud de una curva dada por la función f:[a,b]⟶ℝ, con derivada continua en [a,b], usamos la fórmula L=(∫_a^b)(Sqrt[ 
                1 + (((f' (x)))^2)]) dx.

Como ejemplo calculamos la longitud de la curva dada por la función f(x)=x^2+x+1 entre x=-1 y x=1. Primero dibujamos la gráfica de la función en un intervalo mayor.

f[x_] := x^2 + x + 1
Plot[x^2 + x + 1, {x, -2, 2}]

Y aplicamos la fórmula que hemos visto.

Integrate[Sqrt[1 + f'[x]^2], {x, -1, 1}]

Si en lugar del valor exacto, queremos obtener un valor decimal aproximado, usamos la orden NIntegrate.

NIntegrate[Sqrt[1 + f'[x]^2], {x, -1, 1}]

Veamos ahora la longitud de un arco de la función seno entre x=0 y x=Pi.

Clear[f]
f[x_] := Sin[x]
Plot[Sin[x], {x, 0, Pi}]

Integrate[Sqrt[1 + f'[x]^2], {x, 0, Pi}]

Al igual que en el ejemplo anterior, empleamos la instrucción NIntegrate para obtener un valor decimal aproximado.

NIntegrate[Sqrt[1 + f'[x]^2], {x, 0, Pi}]

Ejercicio: Calcule la longitud de la curva definida por la función f(x)=sin(cos(x)) entre x=1 y x=3.

Area de una superficie de revolución.

Damos en este aparatado la fórmula que permite obtener la superficie que se genera al gira una función f[x] alrededor del eje OX. En concreto, si f:[a,b]⟶ℝ una función con derivada continua en[a,b], con f(x)≥0 para todo x∈[a,b], entonces el área de la superficie que se genera al girar esta curva alrededor del eje OX viene dado por S=2π(∫_a^b) f(
            x) (Sqrt[1 + (((f' (x)))^2)]) dx.

Para ilustrar esta fórmula, vamos a calcular el area de una esfera. Para ello consideramos la mitad superior de un círcunferencia de radio uno y centro en el punto (0,0). Esta circunferencia tiene por ecuación (x^2) + (y^2) = 1, y al despejar y, queda y=±(Sqrt[1 - (x^2)]), donde sólo consideraremos el signo positivo de la raíz.

f[x_] := Sqrt[1 - x^2]
Plot[f[x], {x, -1, 1}]

2*Pi*Integrate[f[x]*Sqrt[1 + f'[x]^2], {x, -1, 1}]

De forma similar vamos a calcular la superficie de la esfera de radio r. Para ello tenemos en cuenta la ecuación de los puntos de la circunferencia de radio r, esto es, x^2+y^2=r^2.

Clear[f]
f[x_] := Sqrt[r^2 - x^2]
S = 
      2*Pi*Integrate[
          f[x]*Sqrt[1 + (f'[x])^2], {x, -r, 
            r}]
Simplify[S, r > 0]

\(Por\ tanto, \ 
    como\ sabemos\ que\ r\ es\ el\ radio\ y\ por\ tanto\ un\ número\ positivo, \ 
    la\ superficie\ de\ la\ esfera\ es\ 4 \(\( πr\^2\)\(.\)\)\)

Volumen de un sólido de revolución (por discos).

Daremos ahora la fórmula que permite calcular el volumen de un sólido de revolución obtenido al girar una función f[x] alrededor del eje OX. 
En concreto, sea f:[a,b]⟶ℝ una función continua en [a,b] con f(x)≥0 para todo x∈[a,b]. Sea S la región limitada por la gráfica de f, el eje OX y las rectas x=a y x=b.

Entonces si S gira alrededor del eje OX genera un sólido de revolución cuyo volumen es V=π (∫_a^b)(((f[
                      x]))^2) dx.

Como ejemplo de esta fórmula, calcularemos el volumen que resulta al girar la parte superior de una elipse respecto al eje OX. En general la ecuación de la elipse viene dada por ((x^2)/(a^2)) + ((y^2)/(b^2)) = 1,donde el eje mayor mide 2a y el eje menor mide 2b. Veremos el caso particular en el que a=3 y b=2.
(Debemos notar que el sólido que resulta es un elipsoide, pero que no todos los elipsoides se obtienen de esta manera.)

Clear[f]
f1[x_] := Sqrt[4 (1 - (1/9) x^2)]
f2[x_] := -Sqrt[
          4 (1 - (1/9) x^2)]
Plot[{f1[x], f2[x]}, {x, -3, 3} , 
      AspectRatio -> Automatic]
Pi*Integrate[f1[x]^2, {x, -3, 3}]

( En la orden Plot anterior se ha usado la opción AspectRatio->Automatic, de forma que Mathematica determina la escala de los ejes.)

De forma similar calculamos el volumen de la esfera de radio r. En este caso consideramos la parte superior de la circunferencia de radio r y centro en el origen de coordenadas.

Clear[f]
f[x_] := Sqrt[r^2 - x^2]
Pi*Integrate[f[x]^2, {x, -r, r}]

Volumen de un sólido de revolución (por tubos)

Damos en esta sección la fórmula para calcular el volumen de un sólido que se ha obtenido mediante la revolución, respecto al eje OY, de cierta función f[x].

Sea f:[a,b]⟶ℝ una función continua en [a,b] de forma que la gráfica de y=f(x) está contenida en el primer cuadrante, es decir que 0≤a≤b y f(x)≥0 para todo xϵ[a,b].

\(Sea\ S\ la\ región\ limitada\ por\ la\ gráfica\ de\ f \((x)\)\), el eje OX y las rectas x = a y x = b .  Entonces, si S gira alrededor del eje OY genera un sólido de revolución cuyo volumen es V=2π(∫_a^b)xf(x)dx. Es decir

Nótese que

Para ilustrar esta fórmula, calculamos el volumen de un toro, haciendo girar un circulo respecto al eje OY. En general podemos considerar un círculo de radio r y con centro en el punto (Rx,0), ya que la altura a la que se encuentre el toro no influye en su volumen. Este círculo tiene ecuación

y podría definirse usando las funciones

f1[x_] := Sqrt[r^2 - (x - Rx)^2]
f2[x_] := -Sqrt[r^2 - (x - Rx)^2]

Para poder hacer gráficas consideramos un caso particular, en concreto tomamos Rx=5 y r=2. Así pues el circulo puede definirse usando las siguientes funciones, de las que dibujamos su gráfica.

g1[x_] := Sqrt[2^2 - (x - 5)^2]
g2[x_] := -Sqrt[2^2 - (x - 5)^2]
Plot[{g1[x], g2[x]}, {x, 5 - 2, 5 + 2}, 
      PlotRange -> {{-7, 7}, {-4, 4}}, 
      AspectRatio -> Automatic]

Para calcular el volumen del toro, consideraremos la mitad superior del círculo (dado por la función g1[x]), y calcularemos el volumen al girar respecto al eje OY. El volumen del toro se hallará multiplicando por dos el número anterior.

Plot[g1[x], {x, 5 - 2, 5 + 2}, 
      PlotRange -> {{-7, 7}, {-4, 4}}, 
      AspectRatio -> Automatic]

La siguiente instrucción (que no es necesario que estudie ahora) dibuja la superficie del 'semitoro' como revolución de la función g1. La opción ViewPoint sirve para indicar el punto del espacio donde se encuentra el punto de vista, cambiando este punto de vista podemos observar la superficie del 'semitoro' desde otro punto.

ParametricPlot3D[{x Sin[t], g1[x], x Cos[t]}, {x, 5 - 2, 5 + 2}, {t, 
        0, 2  Pi}, ViewPoint -> {0, 2, -3}]

ParametricPlot3D[{x Sin[t], g1[x], x Cos[t]}, {x, 5 - 2, 5 + 2}, {t, 
        0, 2  Pi}, ViewPoint -> {0, -2, -3}]

Aplicamos la fórmula vista para calcular el volumen de la mitad superior del toro.

SemiVolumen = 2*Pi*Integrate[x*g1[x], {x, 5 - 2, 5 + 2}]

Así pues, el volumen del toro es el siguiente.

Volumen = 2*SemiVolumen

Volumen por secciones.

Por último calculamos el volumen de un sólido usando secciones mediante planos, y se supone que conocemos el area de las secciones. En concreto se considera un sólido en ℝ^3 de forma que todos sus puntos tienen abscisa comprendida entre dos números reales a y b, y se considera también un plano perpendicular al eje OX, formado por puntos de abscisa x.

Sea A(x) el área de la sección que forma el plano al cortar al sólido. Se supone que la función A:[a,b]⟶ℝ es una función continua con A(x)≥0. Entonces el volumen del sólido viene dado por la fórmula V=(∫_a^b) A(x) dx. Es decir

Como ejemplos de esta sección calcularemos el área del cono y de una pirámide de base cuadrada. Son los mismos ejemplos vistos en las clases de teoría. Recordamos que las dimensiones de las secciones (y en consecuencia el area de las mismas) se calculaban mediante una semejanza de triángulos.

En el primer ejemplo calculamos el volumen del cono de radio r y altura h. Cada sección es un círculo de radio r[x], que se define a continuación, y de ahí se pueden definir las áreas de las secciones. Con la fórmula dada, se puede calcular el volumen del cono.

Clear[A]
r[x_] := r*x/h
A[x_] := Pi*(r[x])^2
Volumen = Integrate[A[x], {x, 0, h}]

En el segundo ejemplo, se calcula el área de la pirámide de base cuadrada (de lado L) y altura h. En este caso las secciones tienen forma cuadrada, con semilado l[x]. Con la definición del semilado en función de x, se tiene el área de cada sección A[x]. El uso de la fórmula dada al principio de esta sección permite calcular el volumen de la pirámide.

Clear[A]
l[x_] := (L/2)*x/h
A[x_] := (2  l[x])^2
Volumen = Integrate[A[x], {x, 0, h}]

Ejercicios

1- Calcule el área y el perímetro de la elipse que tiene por ecuación ((x^2)/25) + ((y^2)/9) = 1.(Solución: área=15 π, perímetro aprox. 25.527). Idem de la elipse que tiene por ecuación ((x^2)/(a^2)) + ((y^2)/(b^2)) = 1.(Indicación: téngase en cuenta al simplificar que a>0, b>0) (Solución: área=a b π, perímetro=4 a EllipticE[1 - ((b^2)/(a^2))])

2- Calcule el área y el volumen de un casquete esférico de altura h y radio r. (Indicación: considere una función que gira alrededor del eje OX. Al simplificar el área, tenga en cuenta que r>0,h>0,h<r, usando una instrucción como Simplify[S,{r>0,h>0,h<r}]    ). (Solución: área=2 π r h, volumen=(1/3)π(3r-h) h^2 )

3- Calcule el volumen del sólido de revolución que se genera al girar alrededor del eje OY, la curva definida por la función p(x)= -x^2+1 entre x=0 y x=1. Idem al girar la curva respecto al eje OX.

4 -  Calcule el volumen del elipsoide de semiejes a,  
    b y c dado por la ecuación
((x^2)/(a^2)) + ((y^2)/(b^2)) + ((z^2)/(c^2)) = 1. 
\(\ \((Indicación : \ 
            considere\ las\ secciones\ que\ producen\ planos\ de\ la\ forma\ x = k, para\ k ∈ \([\(-a\), 
                a]\) . \ ¿Qué\ forma\ tienen\ dichas\ secciones?\ ¿Cuál\ es\ el\ area\ de\ la\ secciones\ para\ cada\ valor\ \(\(k\)\(?\)\))\) . \ \((Solución : \ volumen = 
          4\/3\ a\ b\ c\ π)\)\)